母分散の区間推定

母分散が $\sigma^2$ の正規母集団から抽出された $n$ ケースの不偏分散を $U$ とすると，母分散は次式のように表せる。
$$
\sigma^2 = \frac{(n-1)U}{\chi^2_0}
$$

自由度が $n - 1$ の $\chi^2$ 分布において，下側・上側の確率が $\alpha\ /\ 2$ となるパーセント点をそれぞれ $\chi^2_L$，$\chi^2_U$ とすると，信頼限界は次式で与えられる。

$$
\text{下側信頼限界} = \frac{(n-1)U}{\chi^2_U}
$$

$$
\text{上側信頼限界} = \frac{(n-1)U}{\chi^2_L}
$$

例題

x = [38.37, 45.28, 47.59, 31.74, 37.99, 70.04, 47.70, 57.70, 62.34, 52.08]

の 95 % 信頼区間を求めよ。

using Rmath, Statistics

confidenceintervalofvariance(x; confidence=0.95) = confidenceintervalofvariance(var(x), length(x); confidence)

function confidenceintervalofvariance(U, n; confidence=0.95)
    α = (1 - confidence) / 2
    df = n - 1
    df * U ./ [qchisq(α, df, false), qchisq(α, df)]
end;

x = [38.37, 45.28, 47.59, 31.74, 37.99, 70.04, 47.70, 57.70, 62.34, 52.08];

• デフオルトでは 95% 信頼区間を求める。

confidenceintervalofvariance(x)

2-element Vector{Float64}:
  65.99385658745433
 464.890642631047

• 90% 信頼区間を求めるとき

confidenceintervalofvariance(var(x), length(x), confidence=0.90)

2-element Vector{Float64}:
  74.19986238749816
 377.54682900990946

• 二次データ（不偏分散，サンプルサイズ）を与えるとき

confidenceintervalofvariance(var(x), length(x))

2-element Vector{Float64}:
  65.99385658745433
 464.890642631047

var(x), length(x)

(139.48731222222227, 10)

confidenceintervalofvariance(139.487, 10)

2-element Vector{Float64}:
  65.9937088697284
 464.8896020404209