フィールド.コードで文字の表示非表示を切り替える

フィールドコードとフィールドの違い

どうでも良いが
Word のフィールドコード一覧
としながら
Word でフィールドを挿入、編集、表示する
といつの間にかフィールドになってしまう。

これは中括弧自体はフィールドであり、フィールドは種類を指している。そして、フィールドの文字がフィールドコードらしい。VBAではField.Codeとなっている。

Word.FieldとWord.Rangeの違い

またこの解説で

フィールドのコードを表す Range オブジェクトを返します。値の取得と設定が可能です。

となっているのでWord.Rangeよりは上の概念なのだとわかる。
フィールドの目的はAccessやExcelでも意味合いが違う。
WordにおいてはRangeとはある一定の範囲という意味しかない。長さ0で現在位置でもActiveCellではなく、Selection.Rangeとなる。
この一定の範囲にスィッチを加えて、あるいは外部データ、プロパティ、ドキュメントの他のRangeを引用し、加工して表示できるのがFieldである。
オブジェクト、プロパティまたはRangeまたは外部データ+書式、固有スィッチ＝Field
である。
フィールドを最初に意識するのは一般的に差し込み印刷(Mergefield)であろう。

手順

フィールドコードのDocPropertyのためカスタムプロパティを設定する
ALT+F 情報
プロパティ
詳細プロパティ
プロパティ名Draft

値を変更するときはDraftをクリックして値を変更し、変更をクリック
画面を戻してCTRL+F9でフィールドコードを表示 IF 半角空白を入れる
`{ IF {DocProperty Draft} = "Y" "案1" ""}`
更新する
プロパティを変更して表示を切り替えるときは1.の値の変更を行って、「更新F9」をする
ファイルを他人に渡す場合等はフィールドコードの更新、フィールドのリンクを解除するを実行し、プロパティを削除して別名で保存する。もしくはPDFで発行して、ドキュメント情報を削除する。

ポイント

フィールドコードの式にイコールとカッコはいらない
DocPropertyのYesNoの値はTrue Falseではなく Y N
きちんと半角空白を入れる
非表示は""(NullString)
囲み文字などの装飾が有効
中カッコ{}はCtrl+F9で入れる。この段階で一度保存する。
最後にフィールドを更新して、フィールドのリンクを解除してからプロパティを消して別名で保存する
Optionの設定に注意
文字列を指定する場合には値は255文字まで。それ以上になった場合にはクィックパーツの定型句を使う。

DocProperty以外の方法

フィールドの書き換えで文字列をコントロールする方法としては、隠し文字を使い、オプションで切り替える方法も考えられるが、印刷されないだけで、文字自体は自動で削除されない。
可能かどうかは不明だが、定型句を切り替える方法も考えられる。しかし、定型句自体がテンプレートやbuildingblock.dotxに保存される。Doc*ファイル単体で文字列を切り替える、という方法はこのユーザー設定プロパティとフィールドを組み合わせるしかないようだ。
:C: DocVariableもあるが、これはVBAが必要となる。
この方法が簡単とはいいがたいが、かといってほかの方法が使いやすいとも言えない。マクロを要しない分だけDocpropertyフィールドを使う方が容易だともいえる。

1.フィールドコードの式にイコールとカッコはいらない

フィールドの編集で式からIF関数を選ぶとイコールとカッコがつくが、いらない。

加減乗除の場合は必要だが、この場合は不要。なんで余計なものをつけるんだ。。。

2.DocPropertyのYesNoの値はTrue Falseではなく Y N

このようにDocPropetyを表示すると半角大文字でY/Nが表示される
このため="Y"や="N"というふうに結ばれる。つまり値は文字列だということらしい。
しかし、後述するがマクロではBoolean、つまり通常はTrue Falseが返ってくる。極めて珍しい。
IFフィールドとDocPropertyは
IF statement and DocProperty field as conditional text controls?

{ IF { DOCPROPERTY myproperty } = "whatever" "same" "different" }

このように等価であるかどうかというサンプルしかない。True/Falseではなく、Y or NというのではIFフィールドを使いこなせないのも道理である。

3.きちんと半角空白を入れる

空白が入っているところは必ず空白を入れる。そうしないとエラーが生じる

4. 非表示は`""`(NullString)

3.の画像で表示しているとおり""Noの場合は文字列がない。VBの定数としてはvbNullStringである。これで非表示を作り出している。
こうすると文字データ自体がなくなるので、リンクを解除した段階で文字が削除されたことになる。

5. 囲み文字などの装飾が有効

囲み文字やフォントの大きさなどが指定すると反映されるため、単なる文字列としては扱われていないらしい。
3．の例は囲み文字になっているが、実際にYの場合にはこの設定が反映される。

6.中カッコ`{}`はCtrl+F9で入れる。この段階で一度保存する。

今回の場合2回入れる。IFの前に一度、IFをいれて半角スペースを入れてCtrl+F9をいれてDocProperty Draftと入力。
プロパティ名を英語にしている方が入力が早いしバグの恐れがない。なお、プロパティ名は組み込みプロパティ、関数、定数として扱われるようなものは避けること。たとえばwdCpをつけてプロパティ名をつけるなど。例wdCp_Name wdCp Word CustomDocumentProperty
また、フィールドを入れ終わったら、一旦ファイルを保存する。
今回の記事では影響がないが、組み込みプロパティとリンクしている場合は保存する必要があるとされている。また、せっかく設定したフィールドが飛ぶと通常の入力より手間なので、ダメージが大きい。

DocumentProperties.Add メソッド (Office)

Office ドキュメントの特定の値にリンクしているドキュメントプロパティを DocumentProperties コレクションに追加する場合、DocumentProperty オブジェクトに正しくドキュメントプロパティが追加されているかどうかを確認するには、Office ドキュメントをあらかじめ保存しておく必要があります

最もDocumnt.Containerは通常は使わない。
LinkToContent: = False は必須だが、値を設定してフィールドに使うという目的であれば、Falseで固定とみなしていいと思われる。
LinkSourceはBulitin以外は使わないと思われるし、使うならならばBuiltInそのものを使うだろう。

7. フィールドを更新して、フィールドのリンクを解除してからプロパティを消して別名で保存する

フィールドを操作されても仕方がないので、
ALT+F9でフィールドコードをすべて表示
フィールドをすべて更新する−全選択後F9キー -relief
あるいは公式のHPにあるように印刷前にフィールドを更新でも良い。
フィールドを更新する
CTRL+A -> F9
あるいはフィールドの計算結果だけを表示させるてフィールドを消すことをフィールドのリンクを解除するという。しかし、実際はリンクしていないものばかりである。BuiltInもFalseなので、リンクを解除するものはほぼないというのが実情である。
フィールドのリンクを解除する。 Ctrl + Shift + F9 公式HPでもやはりリンクを解除という訳のわからないタイトルになっている。
CTRL+A -> CTRL+SHIFT+F9
フィールドコードが残っていないかを確認するにはF11キー、Shift+F11キーでフィールドに移動しないかを確認する。完全に消えている場合にはカーソルが移動しない。
word-のキーボード-ショートカット
公式ホームページではここではフィールドとなっている。普通の人がわけがわからなくなるのは当たり前であろう。
なお、フィールドのロックは、ロックを外すのが簡単なのでこういう場合は使うべきではないだろう。
覚えれば上級者！Wordのフィールドに関するショートカットキー

VBA

オプションの定義

OptionをVBAでコントロールすると、Option とか色々混在する。
Wordが出来合いで間に合わせながら作ったいい加減さが伺える。

Viewは

ActiveDocument.ActiveWindow.View.FieldShading = _ 
 wdFieldShadingAlways

とViewオブジェクトが、Document Windowの下にあるというのがポイント

View.ShowBookmarks

True の場合は先頭と末尾の各ブックマークの角かっこが表示

View.ShowFieldCodes

True の場合は、フィールドコードが表示されます。

更新しても実行結果が表示されない

Options.PrintFieldCodes

True の場合Microsoft Word結果の代わりにフィールドコードを印刷します。

下書きの段階で使うときもあるが、通常はFalseで固定したほうが良い。

Options.UpdateFieldsAtPrint

True ドキュメントを印刷する前に自動的にフィールドが更新される
このオプションはTrue推奨

ただし、印刷（PDFへのExportを含む？)を実行すると値が同じでも更新されたことになり、保存を要求されます。
このため、ドラフト段階を終えて、完成した後はこのオプションはFalseにしてもいいと思います。

View.FieldShading
WdFieldShading定数。
通常は2。
ただし最終チェック時に1に切り替えて網掛けにして確認する、という使い方ができる。

Sub WordFieldCodeOption()
    ActiveWindow.View.ShowBookmarks = True
    ActiveWindow.View.ShowFieldCodes = Not ActiveWindow.View.ShowFieldCodes
    Options.UpdateFieldsAtPrint = True
    Options.UpdateLinksAtPrint = True
    Options.PrintFieldCodes = True
End Sub

フィールドの操作

フィールドを実行結果とフィールドコードに切り替えるのをオプションで実行
混在している場合に統一したい場合は使える。

Sub toggleShowWordFieldCodes()
    ActiveWindow.View.ShowFieldCodes = Not ActiveWindow.View.ShowFieldCodes
End Sub

すべてのフィールドコードを実行結果をコードに切り替えるまたはその逆。
ただしToggleなので、フィールドコードはすべて実行結果（F9更新）していることが前提。
混在する場合はオプションで切り替える。

Sub ShowAllFieldcodes()
    Selection.WholeStory
    ActiveWindow.View.ShowFieldCodes = Not ActiveWindow.View.ShowFieldCodes
End Sub

フィールドが実行結果を表示している状態で、個々のフィールドを更新する

Sub runUpdateFields()
' built in Macroで実行する
Dim wFld As Word.Field
For Each wFld In ThisDocument.Fields
wFld.Select
Application.Run MacroName:="UpdateFields"　' 組み込みマクロを利用
' wfld.Update 'でもよい
Next
End Sub

Ctrl+AとF9で更新した場合のマクロ
フィールドコードはすべて実行結果（F9更新）していることが前提。

Sub WordDocumentAllFieldUpdate()
' フィールドコードが実行結果を表示している状態で実行
    Selection.WholeStory
    Selection.Fields.Update
End Sub

フィールドコードの挿入

今回の案1が囲み文字で表示されるマクロ
カーソル位置に挿入される。
キーボード操作の記録で作成したためか、囲み文字を設定すると一度空白をいれて切らないといけない。また囲み文字属性があるときは逆転するので注意。書式を一度クリアして、標準スタイルのような状態で実行すること。

Sub InsertFieldCode()
    Selection.Fields.Add Range:=Selection.Range, Type:=wdFieldEmpty, _
        PreserveFormatting:=False
    Selection.TypeText Text:="IF "
    Selection.Fields.Add Range:=Selection.Range, Type:=wdFieldEmpty, _
        PreserveFormatting:=False
    Selection.TypeText Text:="Docproperty Draft"
    Selection.MoveRight Unit:=wdCharacter, Count:=2
    Selection.TypeText Text:=" =""Y"" ""案1"""
    Selection.MoveLeft Unit:=wdCharacter, Count:=1
    Selection.MoveLeft Unit:=wdCharacter, Count:=2, Extend:=wdExtend
    With Selection.Font.Borders(1)
        If .LineStyle = wdLineStyleNone Then
            .LineStyle = Options.DefaultBorderLineStyle
            .LineWidth = Options.DefaultBorderLineWidth
            .Color = Options.DefaultBorderColor
        Else
            .LineStyle = wdLineStyleNone
        End If
    End With
    Selection.Font.Shrink ’グリッドを超える時があるので縮小している
    Selection.MoveRight Unit:=wdCharacter, Count:=2
    Selection.TypeText Text:=" """""
    Selection.Fields.Update
End Sub

ユーザーが設定するプロパティをVBAで設定、変更、削除する

Document.CustomDocumentProperties プロパティ (Word)

Properties of type msoPropertyTypeString (MsoDocProperties) cannot exceed 255 characters in length.
msoPropertyTypeString 型のプロパティ (MsoDocProperties) の長さは 255 文字を超えることはできません。

とあるが、文字列の値の長さが255文字という意味だと思われる。
これを超える場合にはクィックパーツの定型句（AutoText)を使う。

DocumentProperty.Value プロパティ
 DocumentProperty.LinkSource プロパティ (Office)
このユーザーが設定する詳細プロパティをCustomPropertiesのコレクションとしている。
Draftと名前がかぶると大変なので、Testファイルかどうかを意味するTestFileというプロパティを設定する。
Yes/No型で、最初のValueはTrueとする

Sub AddUserCustomProperty_TestFile_Boolean_True()
ThisDocument.CustomDocumentProperties.Add _
Name:="TestFile", LinkToContent:=False, Value:=True, _
Type:=msoPropertyTypeBoolean
End Sub

次に変更する。勘のいい人ならこれは名前で指定だろうと予測できるだろう。Index番号もあるが、追加したり削除したりすれば変わるので、名前指定のほうが実際は使えると思われる。
またこの前段の上位オブジェクトであるDocumentも要注意である。
ActiveDocument Thisdocument 開いているファイルの名前を指定する
といいうことが考えられる。
とりあえずモジュールを設定しているDocumentとしてサンプルを記述する。
Document.CustomDocumentProperties プロパティ (Word)
MsoDocProperties
msoPropertyTypeNumber 1 整数型 (Integer) の値
マクロで設定すると整数型を設定することができる。
面白いのは、返すのはDocumentProperties オブジェクトとしているが、このオブジェクトはWordではaddメソッド以外全く使えないオブジェクトです。
Countすらできない。BuiltInかCustomを使用する。またWordではなくOfficeのオブジェクトになる。
Office VBA リファレンス DocumentProperties オブジェクト DocumentProperties のメンバー DocumentProperties.Add メソッド (Office)

整数型を設定すると小数点がカットされることが確認できるサンプルコード

Sub AddUserCustomProperty_IntTest_Boolean_True()
ThisDocument.CustomDocumentProperties.Add _
Name:="IntTest", LinkToContent:=False, Value:=41.1, _
Type:=msoPropertyTypeNumber
End Sub

例えばこのようにすると数値は41になる。
ご存知の方もいるかも知れないが、Wordも演算誤差が生じるので、整数型で設定できるものは整数型で設定したほうが良い。
また、小数点が含まれるものは、必ず表示形式（スィッチ）を設定し、小数点切り捨て、四捨五入が行われるようにすること。

Sub UpdateUserCustomProperty_TestFile_Boolean_False()
ThisDocument.CustomDocumentProperties("TestFile").Value = False
End Sub

削除

ThisDocument.CustomDocumentProperties("IntTest").Delete

まとめ

案を切り替える、ドラフトを切り替えるというのはユーザープロパティの値を変更して、更新をかけるだけでできるようになる。
1つ2つなら手作業でも良いが、5を超える場合はこれでかなりの時短になる。
相手方にファイルを渡さずPDF等で渡せば、別にファイルを保存する必要もない。
完全に動くかどうかは不明だが、一応単純なフィールドコードであれば、このようにシンプルにまとまる。
Subがついていないものは適宜追加すること。

オプションの定義

    ActiveWindow.View.ShowBookmarks = True
    ActiveWindow.View.FieldShading = wdFieldShadingWhenSelected
    ActiveWindow.View.ShowFieldCodes = False
    Options.UpdateFieldsAtPrint = True
    Options.UpdateLinksAtPrint = True

プロパティ定義

On Error Resume Next
ThisDocument.CustomDocumentProperties("Draft").Delete
ThisDocument.CustomDocumentProperties.Add _
Name:="Draft", LinkToContent:=False, Value:=True, _
Type:=msoPropertyTypeBoolean

挿入

カーソルがある位置に挿入DraftがTrueなら"Drafts"と表示

With Selection
    .Fields.Add Range:=Selection.Range, Type:=wdFieldEmpty, _
        PreserveFormatting:=False
    .TypeText Text:="IF "
    .Fields.Add Range:=Selection.Range, Type:=wdFieldEmpty, _
        PreserveFormatting:=False
    .TypeText Text:="DocProperty Draft"
    .MoveRight Unit:=wdCharacter, Count:=2
    .TypeText Text:=" = ""Y"" ""Drafts"" """""
    .Fields.Update
End With

保存

更新

Sub FieldUpdate()
ThisDocument.CustomDocumentProperties("Draft").Value = False
ThisDocument.Fields.Update
End Sub

最終処理

Sub TerminalFieldsUpdateAndUnlink()
ThisDocument.Fields.Update
ThisDocument.Fields.Unlink
ThisDocument.CustomDocumentProperties("Draft").Delete
End Sub