したこと
「minicondaのポータブルインストール」を参考（ほとんどそのまま）に、Mambaforgeでポータブル版のJupyterLabを作った。
また、「JupyterLab3.0の起動ブラウザを指定する方法」を参考に、JupyterLabをChromeのアプリモードで起動できるようにもしてみた。
Mambaforgeとは
mambaとはAnacondaやMinicondaで使われているパッケージマネージャーcondaより高速で互換なパッケージマネージャーである。
mambaでパッケージをインストールするとき、conda-forgeからパッケージをインストールする機会が多くある。このとき、
mamba install -c conda-forge パッケージ名
のように、チャンネルを指定するため-c conda-forgeをつける必要がある。
しかし、Mambaforgeはconda-forge に特化しているので
mamba install パッケージ名
とするだけでよい。
（参考）
-
mambaについて GitHub - mamba-org/mamba - Mambaforgeについて GitHub - conda-forge/miniforge
環境設定用のバッチファイル
最初に作る。JupyterLabのインストール用バッチファイルや起動用バッチファイルで環境設定をするために呼び出して使う。
@echo off
cd /d %~dp0
SET MAMBA_PATH=%~dp0Mambaforge
SET PATH=%MAMBA_PATH%;%MAMBA_PATH%\Scripts;%MAMBA_PATH%\Library\bin;%MAMBA_PATH%\condabin;%PATH%
SET USERPROFILE=%~dp0UserProfiles
SET LOCALAPPDATA=%USERPROFILE%/appdata/Local
SET APPDATA=%USERPROFILE%/appdata/Roaming
SET JUPYTER_CONFIG_DIR=%USERPROFILE%
call mamba.bat activate base
MambaforgeとJupyterLabのインストール用バッチファイル
@echo off
cd /d %~dp0
SET MAMBA_PATH=%~dp0Mambaforge
SET INSTALLER=%~dp0Mambaforge-Windows-x86_64.exe
IF not EXIST %INSTALLER% (
bitsadmin /TRANSFER Mambaforge https://github.com/conda-forge/miniforge/releases/latest/download/Mambaforge-Windows-x86_64.exe %INSTALLER%
)
IF not EXIST %MAMBA_PATH%\python.exe (
mkdir %MAMBA_PATH%
%INSTALLER% /S /InstallationType=JustMe /AddToPath=0 /RegisterPython=0 /NoRegistry=1 /D=%MAMBA_PATH%
)
call environment_settings.bat
call mamba install nodejs jupyterlab jupyterlab-language-pack-ja-JP jupyterlab_code_formatter black isort -y
mkdir NoteBooks
WindowsのMinicondaのインストーラーには、サイレントモードというのがあり、オプションをつけて実行することにより、ポータブル化することができる。
「Installing on Windows -- conda」から引用すると、
To run the the Windows installer for Miniconda in silent mode, use the
/Sargument. The following optional arguments are supported:
/InstallationType=[JustMe|AllUsers]---Default isJustMe./AddToPath=[0|1]---Default is0/RegisterPython=[0|1]---Make this the system's default Python.0indicates Python won't be registered as the system's default.1indicates Python will be registered as the system's default./S---Install in silent mode./D=<installation path>---Destination installation path. Must be the last argument. Do not wrap in quotation marks. Required if you use/S.
上記に加えて、/NoRegistry=1は「minicondaのポータブルインストール」によると、
windowsのプログラムとしてインストーラーを登録しない
ということである。
そして、「GitHub - conda-forge/miniforge」に
It can be compared to the Miniconda installer.
と記述があるので、Mambaforgeのインストーラーにも利用できると考え、実行した。ポータブル化できているようである。
（参考）
JupyterLabをChromeのアプリモードで開くための構成ファイル
c = get_config()
c.ServerApp.browser = '"C:\\Program Files\\Google\\Chrome\\Application\\Chrome.exe\" --app=%s --start-maximized --force-dark-mode'
- Chromeの設定に使うだけなので、この２行だけでよい。
- Pythonでは(半角)￥マークの代わりに
\が使われるが、エスケープシーケンスを用いて\\としなければならない。Windowsでは(半角で)￥￥と表示される。（自分なりの解釈） -
--app=<URL>でアプリモードで起動する。アプリモードとは、Chromeをアドレスバーやタブバーを省略した状態で起動し、Webアプリ化したもの。 -
%sはJupyterLab Serverの作成したURLを指す。 -
--start-maximizedで、ウィンドウを最大化して起動する。 - 最後の
--force-dark-modeはダークモードが好きだから付けてるだけ。削除してよい。
（参考）
JupyterLab起動用のバッチファイル
@echo off
call environment_settings.bat
jupyter-lab.exe --config=chrome_config.py ./NoteBooks
最後の行を
cmd
または
powershell
に変えるとコンソールを開くことができる。
ドライブ・フォルダを変更したときPythonのkernelへのパスを修正するバッチファイル
@echo off
call environment_settings.bat
python -m ipykernel install --user
（参考） Installing the IPython kernel
追加情報
environment_settings.batに
SET JUPYTER_CONFIG_DIR=%USERPROFILE%
の一行を追加した。
こうすると、chrome_config.pyのファイル名をjupyter_lab_config.pyに変えて、%USERPROFILE%で指定したフォルダに置けばstart_jupyter.batの最後の行を
jupyter-lab.exe ./NoteBooks
とすることもできる。
何故こうしなくて、--config=chrome_config.pyで指定しているのかというと、chromeの設定だけということの明示と、設定をテストしていじっているときに、いちいちフォルダを移動するのが面倒だったから。
jupyter_lab_config.pyは、コンソールを開き、
jupyter lab --generate-config
とすると、%USERPROFILE%で指定したフォルダに作られる。
このjupyter_lab_config.pyを編集することによって、JupyterLabを開くブラウザの指定やnotebookの初期フォルダの設定などいろいろなことができる。