Windows:電源プラン切り替えのショートカットを作成するスクリプト

概要

電源プランの切り替えを複雑なコントロールパネルからではなく、デスクトップから一発で切り替え出来るショートカットを作成します。
一つ一つ手で作ることも可能なようですが、WBEMから設定を抜き取ったほうが確実でしたのでVBスクリプトを使います。

なお、カスタム設定をショートカット化する場合は、スクリプト実行前に電源コントロールパネルから作成しておく必要があります。

スクリプト

MakePowerCfgSC.vbs

Option Explicit
Dim oQrys,oItm
Dim oWsh,oSC,oProp,oFN,oGUID

Set oWsh = CreateObject("WScript.Shell")
Set oQrys = CreateObject("WbemScripting.SWbemLocator").ConnectServer(,"\Root\CIMV2\power").ExecQuery("Select * From Win32_PowerPlan")

For Each oItm In oQrys
	oGUID = oItm.InstanceID
	oGUID = Mid(oGUID,InStr(oGUID,"{")+1)
	oGUID = Left(oGUID,InStr(oGUID,"}")-1)

	oFN = oWsh.SpecialFolders.Item("Desktop") & ".\" & oItm.ElementName & ".lnk"
	
	Set oSC = oWsh.CreateShortcut(oFN)
	oSC.TargetPath   = "powercfg.exe"
	oSC.Arguments    = "/setactive " & oGUID
	oSC.WindowStyle  = 7 'Minimized
	oSC.IconLocation = "powercpl.dll,0"
	oSC.Description  = oItm.ElementName
	oSC.Save
Next

使用方法

1. コントロールパネルから電源プランを追加、編集する
2. 電源プランショートカット作成スクリプトを保存
3. スクリプトを実行
4. 電源プランショートカットの利用

電源プランの作成

変更したい電源プランを事前に作成しておきます。
最近のWindows10では「バランス」しか登録されていないため、この状態でショートカットを作成してもあまり意味がありません。

ショートカットカット作成スクリプトを保存

スクリプトを拡張子vbsとして保存してください。

スクリプトの実行

管理者権限で実行したコマンドプロンプトから
cscript MakePowerCfgSC.vbs
という感じにスクリプトを指定して実行して下さい。
Windows10等ではセキュリティが強化され、スクリプトのダブルクリックによる実行（管理者権限無しで実行）が出来ません。

powercfgコマンドに適切なスイッチを追加したショートカットが、電源プランの数だけ作成されます。
必要なものだけを拾って適切な場所に配置してお使い下さい。

電源プランショートカットの作り方

電源プランショートカットをダブルクリック等で実行すると、即座に電源設定が切り替わります。