More than 3 years have passed since last update.

自作のROS対応ロボットを制作しよう！

Last updated at 2021-09-01Posted at 2021-06-18

本記事の目的

rosserialを使用してArduinoとROSの通信を行い、簡易的なROS対応ロボットを作成します。

環境

本記事は以下の環境で実験しています.

項目	バージョン
Ubuntu	18.04
ROS	Melodic

ロボットの制作

材料と機具は以下のものを使用しました。

以下のように寸法と穴の位置を決めていきます。今回は三段構造のロボットなので三枚分穴の位置を決めます。

穴の位置を電動ドリルで開けてねじでそれぞれの部品を固定します。

以下の画像が一段目になります。

左画像が二段目、右画像が三段目になります。

最終的に上記三段を組み合わせて以下のようなロボットを組み立てます。

Jetson nanoの設定

以下の記事を参考に進めてください。

Arduino IDEのインストール

今回モータ制御にはArduinoを使用するため、ArduinoとROSの間で通信を行えるrosserialを使用できる環境を構築します。

ますはIDEをこちらからダウンロードします。

Linux 64 bitsリンクをクリックすると、arduino-1.8.13-linux64.tar.xzがダウンロードできます。

以下のコマンドに従って、展開とインストールを行います。

$ cd ~/Download
$ tar Jxfv arduino-1.8.13-linux64.tar.xz
$ mv arduino-1.8.13 /home/user/
$ cd arduino-1.8.13
$ sudo ./install.sh

[sudo] password for ramune: 
Adding desktop shortcut, menu item and file associations for Arduino IDE...

done!

Arduino IDEにrosserialインストール

以下のコマンドを順に実行することでIDEをインストールする事が出来ます。

$ sudo apt-get install ros-melodic-rosserial
$ sudo apt-get install ros-melodic-rosserial-arduino
$ cd arduino-1.8.13/libraries/
$ rosrun rosserial_arduino make_libraries.py .

Arduino rosserial 動作確認

以下のコマンドを実行することでArduinoとROSを接続します。問題なく接続出来れば成功です！

$ sudo chmod 666 /dev/ttyACM0
$ rosrun rosserial_python serial_node.py /dev/ttyACM0 _baud:=115200

ROSとArduinoの通信を行う

それでは実際にROSとArduino間で通信を行ってロボットを動かしてみましょう！今回はROS側からcmd_velを受け取って、それをPWMに変換してモーターに加えるという一番シンプルな動作を行おうと思います。

以下Arduinoで使用するcodeです。

#include <ros.h>
#include <ArduinoHardware.h>
#include <geometry_msgs/Twist.h>

/***********************************************************************
 * Macro
 **********************************************************************/
#define EN_L 12
#define IN1_L 7
#define IN2_L 8

#define EN_R 11
#define IN1_R 5
#define IN2_R 6

/***********************************************************************
 * Global variables
 **********************************************************************/
double w_r = 0.0;
double w_l = 0.0;

//wheel_rad is the wheel radius ,wheel_sep is
double wheel_rad = 0.03;
double wheel_sep = 0.32;

double speed_ang = 0.0;
double speed_lin = 0.0;

/***********************************************************************
 * Function
 **********************************************************************/
void messageCb( const geometry_msgs::Twist& msg){
  speed_ang = msg.angular.z;
  speed_lin = msg.linear.x;
  w_r = (speed_lin/wheel_rad) + ((speed_ang*wheel_sep)/(2.0*wheel_rad));
  w_l = (speed_lin/wheel_rad) - ((speed_ang*wheel_sep)/(2.0*wheel_rad));
}

// ROS
ros::NodeHandle nh;
ros::Subscriber<geometry_msgs::Twist> sub("cmd_vel", &messageCb );

/***********************************************************************
 * prottype
 **********************************************************************/
void Motors_init();
void MotorL(int Pulse_Width1);
void MotorR(int Pulse_Width2);

void setup(){
  Motors_init();
  nh.initNode();
  nh.subscribe(sub);
}

void loop(){
  MotorL(w_l * 30);
  MotorR(w_r*  30);
  nh.spinOnce();
}

/***********************************************************************
 * Function
 **********************************************************************/
void Motors_init(){
    pinMode(EN_L, OUTPUT);
    pinMode(EN_R, OUTPUT);
    pinMode(IN1_L, OUTPUT);
    pinMode(IN2_L, OUTPUT);
    pinMode(IN1_R, OUTPUT);
    pinMode(IN2_R, OUTPUT);
    digitalWrite(EN_L, LOW);
    digitalWrite(EN_R, LOW);
    digitalWrite(IN1_L, LOW);
    digitalWrite(IN2_L, LOW);
    digitalWrite(IN1_R, LOW);
    digitalWrite(IN2_R, LOW);
}

void MotorL(int Pulse_Width1){
 if (Pulse_Width1 > 0){
     if (Pulse_Width1 > 240) {
        Pulse_Width1 = 240;
     }

     analogWrite(EN_L, Pulse_Width1);
     digitalWrite(IN1_L, LOW);
     digitalWrite(IN2_L, HIGH);
 }

 if (Pulse_Width1 < 0){
     Pulse_Width1=abs(Pulse_Width1);
     if (Pulse_Width1 > 240) {
        Pulse_Width1 = 240;
     }

     analogWrite(EN_L, Pulse_Width1);
     digitalWrite(IN1_L, HIGH);
     digitalWrite(IN2_L, LOW);
 }

 if (Pulse_Width1 == 0){
     analogWrite(EN_L, Pulse_Width1);
     digitalWrite(IN1_L, LOW);
     digitalWrite(IN2_L, LOW);
 }
}

void MotorR(int Pulse_Width2){
 if (Pulse_Width2 > 0){
     if (Pulse_Width2 > 240) {
        Pulse_Width2 = 240;
     }

     analogWrite(EN_R, Pulse_Width2);
     digitalWrite(IN1_R, LOW);
     digitalWrite(IN2_R, HIGH);
 }

 if (Pulse_Width2 < 0){
     Pulse_Width2=abs(Pulse_Width2);
     if (Pulse_Width2 > 240) {
        Pulse_Width2 = 240;
     }
     
     analogWrite(EN_R, Pulse_Width2);
     digitalWrite(IN1_R, HIGH);
     digitalWrite(IN2_R, LOW);
 }

 if (Pulse_Width2 == 0){
     analogWrite(EN_R, Pulse_Width2);
     digitalWrite(IN1_R, LOW);
     digitalWrite(IN2_R, LOW);
 }
}

やっている事は非常にシンプルで、ROS側から受け取ったcmd_velをコールバック関数内で左右の角速度に変換し、loop内でその値に一定値をかけてモーターにPWMを印加しています。モーターに負荷がかかりすぎないように、今回はPWMを240でサチュレーションしています。ピン設定などは使用するモーター環境に合わせてください。基本的にはピンをきちんと指定すれば問題なく動かせると思います。

動作確認

まずは上記のcodeをArduinoに書き込みます。

次にjetson nanoとssh接続します。ssh接続を行うにはIPアドレスとユーザー名とPWが必要なので事前に控えておいてください。

ssh ユーザー名@192.168.xxx.xxx

成功したら、以下のコマンドを順に実行して動作確認を行います。

$ sudo chmod 666 /dev/ttyACM0
$ rosrun rosserial_python serial_node.py /dev/ttyACM0
$ rosrun teleop_twist_keyboard teleop_twist_keyboard.py

以下のように八方向移動とその場旋回が出来れば成功です！(あまりきれいではありませんが・・・（笑）)

まとめ

詳細な設計はせずに誰でも制作可能な簡易版ロボットを制作しました
rosserialを用いてROSと通信を行い、cmd_velでロボットを八方向に動かしました

You get articles that match your needs
You can efficiently read back useful information
You can use dark theme

What you can do with signing up