温湿度センサDHT11をライブラリなしで使ってみた【Arduino】
記事の内容
倉庫や部屋の環境データを、モニタリングして制御できたらいいなと思い、ArduinoとDHT11搭載温湿度センサモジュールを使って、温度と湿度のデータを取得してみました。
外部のライブラリを使わずに通信しているので、多少難易度は高いですが理解しやすくなっていると思います。和訳したデータシートも交えながら、詳しく解説していきます。
使用したArduinoボードは、 Arduino Uno R3 と、 Arduino Mega 2560 R3 (互換品)、プログラム開発環境は Arduino IDE です。
おそらく他のボードでも応用可能だと思いますので、参考にしてもらえると幸いです。
DHT11の説明
DHT11 とは、AOSONG社製の温湿度センサです。温度(Temperature)と相対湿度(Relative humidity)を計測することができます。なぜこのセンサを選んだのかというと、アマゾンで購入した「ELEGOO Arduino用のMega2560スタータキット最終版」に付属していたからです。
単品でも、秋月電子通商で温湿度センサモジュール DHT11として販売されています。
精度は、温度が±2℃、湿度が±5%RHと、そこまで良くはありませんが、値段相応だと思います。簡単な温湿度測定には十分でしょう。
データはデジタル出力となっており、1-Wireライク通信でデータを送信します。端子は3本しかなく（1本は不使用）、2本が電源用で、もう1本が通信用です。
1-Wireとは通信プロトコルの1種であり、複数のセンサをたった1本の信号線で接続できます。そのため、信号線や端子がかなり節約できるというメリットがあります。
しかし、DHT11の場合は1-Wire"ライク"通信であり、1つのセンサでまるまる1本の信号線を占有します。UART通信ともよく似ています。
DHT11をArduinoに接続してみよう！
軽い説明は終わりましたので、続いてArduinoとの接続方法について説明していきます。
ピン配置
上図は、データシートにあるDHT11の寸法図です。
DHT11センサー本体には、4本の足（①~④）が出ています。これらの役割は、
①VCC 電源用ピン（3.3~5.5V入力）
②DATA シリアル通信用ピン（データ転送用）
③NC 未接続ピン（空のピン）
④GND 接地（0V入力）
となっています。すなわち、4本の足のうち1本使用されていないため、実質は3本しか使わないことになります。
という訳で、モジュール化された部品（図2）では、ピンは3本になっています。ピン配置が変更されていることに注意してください。
回路図
DHT11を、マイクロプロセッサ（マイコン、ICなど）に接続した例が上図になります。
少し分かりにくいので箇条書きにすると、
DHT11---> Arduino
①VCC-----> 5Vピン
②DATA----> Port Pin (電圧の入出力ができるピン)
③GND-----> GNDピン
となります。3本つなげれば良いだけなので楽チンですね！
また、DHT11のDATAピンはプルアップされた状態で通信するので、Arduinoの5Vピンと、DATAピンとの間にプルアップ抵抗を接続する必要があります。今回使用するモジュールには、4.7kΩの抵抗が内蔵されているので、Arduinoの5VポートとDATAピンとの間に抵抗を追加する必要はありません。
DHT11と通信してみよう！
通信の流れ
上図は、データシートに記載されている通信のタイミング図になります。
濃い線がArduinoからの信号で、薄い線がDHT11からの信号です。時間経過（左から右）でDATAピンの電圧が上下し、データが送信されているのが読み取れます。
-
信号の順序は、
- ①開始信号(Start signal)
- ②応答信号(Response signal)
- ③湿度・温度データ
- ④終了信号(Low end)
となっています。
①開始信号(Start signal)
Arduino側からの、通信の開始を宣言する18~50ms(18000~50000µs)のLOW信号です。
通信の開始を宣言する信号です。ホスト(Arduino)が18~50ms(標準20ms)の間、DATAピンの電圧をLOW(0V)にします。開始信号が終了すると、電圧はHIGH(5V)に戻ります。
②応答信号(Response signal)
開始信号に対して、DHT11側から返答される信号です。LOWとHIGHが約80µsずつ出力されます。
開始信号を受信したDHT11は、直後に78~88µsのLOW信号を出力します。出力後は、80~92µsのHIGH信号を出力します。
③湿度・温度データ
40ビット分の計測データを出力します。50µsのLOW出力が40回繰り返され、その合間のHIGH出力の長さで、0と1が区別できます。
実際の信号
波形を見るために、研究室からオシロスコープを借りてきました。
実際にDHT11に開始信号を送ってみると、なんか波形が返ってきているのが分かります。
これが、応答信号、データ、終了信号です（開始信号に対して短いので潰れてますが）。
まるで、宇宙からの声明が受信できたみたいでワクワクしますね！
拡大してみると、開始信号が終了した直後、応答信号が届き、その後データ信号が着々と送られてくるのが分かります。
データ信号を拡大すると、確かにHIGH出力の長さが変化していますね。波形を見た感じでは、DHT11は正しく動作しているみたいです。
注意点
データシートには、運用の際の注意点がいくつか提示されています。主に以下の点にご注意ください。
・ノイズの影響や電力不足を防ぐため、接続線は5m未満推奨。3.3V電源のときはできるだけ短く。
・回路の発熱の影響を受けやすいので、発熱部品から離したり空冷したりする必要がある。
・化学薬品（酸化性ガス、硫化ガスなど）の影響で、値が変わったり壊れたりする危険性あり。
・信頼性の問題上、安全装置等には使用禁止。
温度と湿度のデータを取得してみよう！
ArduinoIDEでプログラムを書く
DHT11のことが結構分かってきたでしょうか？
それでは、温度と湿度のデータをArduinoで取得しモニタリングができるように、Arduino IDEでプログラムを書いていきましょう！
通常であれば、そのセンサのために準備されたライブラリを探してダウンロードし、プログラミングしていくのでしょうが、 ライブラリを探すとか入れるとかってめんどくさいし、 せっかく通信について理解を深めたのですから、今回は何も使わずに通信プログラムを書いていきます。
接続さえできていれば、プログラムをコピペするだけでいい！ という超絶メリットもありますね。
以下は、 ArduinoでDHT11からの温湿度データを5秒ごとに取得し、シリアルモニタに出力するプログラム になります。
#define signalPin 7 //デジタルピン7を使用(DHT11のDATAピンと接続)
void setup() {
Serial.begin(9600);
pinMode(signalPin, INPUT_PULLUP);
}
void loop() {
pinMode(signalPin, OUTPUT); //開始信号・・・・・・☆
delay(20);
pinMode(signalPin, INPUT); //開始信号 終了
delay(1000); //1秒待つ
while(1){
readDHT11(); //データの読み取り
delay(5000); //5秒待つ
}
}
//DHT11センサから値を読み取り、シリアルモニタに出力する
void readDHT11() {
byte dataBit = 40; //データ数は40
byte stdTime = 50; //データが0か1か判断する基準時間
bool data[dataBit]; //データ格納用の配列（0か1）
int toggleTime[dataBit]; //波形が切り替わるのにかかった時間
pinMode(signalPin, OUTPUT); //開始信号・・・・・・☆
delay(20);
pinMode(signalPin, INPUT);
countBit(HIGH); //初期波形High
countBit(LOW); //応答時間Low
countBit(HIGH); //応答信号High
for (int i = 0; i < dataBit; i++) {
countBit(LOW); //データLow
toggleTime[i] = countBit(HIGH); //データHighの時間を取得
}
for (int i = 0; i < dataBit; i++) {
if (toggleTime[i] == 0) {
//波形の時間が0→エラー
goto error;
}
data[i] = (toggleTime[i] > stdTime); //基準よりHighの時間が長いと1
}
byte HumH, HumL; //Humidity:湿度のHigh,Lowデータ
byte TemH, TemL; //Temperature:温度のHigh,Lowデータ
byte Check; //Check bit:数値漏れチェック用のデータ
//データの格納
for (int i = 0; i < dataBit; i++) {
if (i < 8) {
//Humidity High(湿度の整数部)
HumH *= 2; //シフト演算（ビットを左にずらす）
HumH += data[i];
} else if (i < 16) {
//Humidity Low(湿度の小数部)=0(省略可)
HumL *= 2;
HumL += data[i];
} else if (i < 24) {
//Temperature High(温度の整数部)
TemH *= 2;
TemH += data[i];
} else if (i < 32) {
//Temperature Low(温度の小数部)
TemL *= 2;
TemL += data[i];
} else if (i < 40) {
//Check bit(チェックビット)
Check *= 2;
Check += data[i];
}
}
float Humidity = HumH + (HumL / 10.0);
float Temperature = TemH + (TemL / 10.0);
if (Check == (HumH + HumL + TemH + TemL)) {
Serial.println(String(Temperature) + "℃ " + String(Humidity) + "%RH");
} else {
goto error; //各データの和とチェックビットが違う→エラー処理
}
if (0) {
//エラー処理
error:
Serial.println("ERROR:Data is wrong!");
}
}
inline int countBit(bool pinV) {
//信号電圧がpinVの間ループする
byte breakTime = 200; //ループを抜け出す時間[µs](無限ループ防止)
unsigned long Time = micros();
while (digitalRead(signalPin) == pinV) {
if ((micros() - Time) > breakTime) {
//波形が長すぎる→エラー処理
goto error;
}
}
return micros() - Time;
error: //エラー処理
return 0;
}
処理の割に、随分長いプログラムになってしまいましたが…
その代わり、コピペして デジタルポート7ピンとDATAピンを繋げば、 即座に温度と湿度のデータが得られます（下写真）。
開始信号の謎
以下は、開始信号を出力するプログラムです。
pinMode(signalPin, OUTPUT); //開始信号・・・・・・☆
delay(20);
pinMode(signalPin, INPUT); //開始信号 終了
pinMode()は、指定したピンの入出力方向を決める関数です。
pinMode(signalPin, OUTPUT); でDATAにLOW信号が出力され、20µs後、pinMode(signalPin, INPUT); でHIGH電圧に戻ります。
これで、前述した開始信号を出力できます。
しかし、書いておきながら**「なぜこれで開始信号が出せるんだ!?」**状態です。
ピンの出力方向を変えてるだけですから。おそらく、プルアップ中なのでピンをOUTPUTにすると電流がマイコンに流れてDATAがLOWになる…という感じなんでしょうが…（ポート操作でDDRxを操作するだけではLOW出力になりませんでした）
また、pinMode(signalPin, INPUT) のINPUTをINPUT_PULLUPにすると最初の計測時だけ信号が乱れ、エラーになります。INPUT_PULLUPにしたときはマイコンのプルアップ抵抗が悪さをしている?ぽいんですが確信が持てません。
だれか詳しい方がいれば教えて下さると助かります。
###フローチャート
プログラムのフローチャートは以下の通りです。
応用のために最適化してない部分がありますが、とりあえずloop()関数内でreadDHT11()関数を走らせれば温湿度データをシリアルモニタに出力できます。
得られた値によって、ファンを稼働させたり、ヒーターを付けたりなどの処理を行いたい場合は、readDHT11()内のローカル変数Humidity（湿度）、Temperature（温度）を利用するといいと思います。
プログラムを書き換えるときの注意点
今回のプログラムではデータ通信にデジタルピン7を使っていますが、他のピンを使いたい場合は#define signalPin 7 の"7"を自分の使いたいピンの番号にしてください(5,10,A3など)。
また、DHT11は 前回の開始信号を送った時のデータを出力します。
つまり今回のプログラムの場合は、約5秒前のデータが出力される ことになります。計測間隔をとても長くする場合やリアルタイムの時間を取得したい場合は、
かと言って、計測の待機時間が短すぎるとエラー率が格段に高まるので（下写真）、開始信号の送信には2秒以上の間隔を空けることを推奨します。
他の機器との通信への応用
今回のプログラムでは下手にライブラリを使っていませんので、信号からデータを取得する部分は他のセンサとの通信にも応用が利くと思います。しかし、すこし複雑な通信方式（I2C, SPIなど）になると、プログラムが難しくなり可読性も著しく低下するので、大人しくライブラリを使ったほうが無難です（使わないほうが通信の理解力は鍛えられます）。
また、信号の取得にdigitalRead()関数とmicros()関数を使っていますが、digitalRead()の実行には3~6µsもかかりますし(Arduino Unoの場合)、micros()の分解能は4µsになっています。そのため、最大でも100kHz程度までの通信しかできないと思われます。
※それ以上の速度で通信したい場合は、直接マイコンのポートを操作する必要があります。
Arduino 日本語リファレンス ポート操作
## 終わりに
今回は、DHT11で温湿度データを取得するプログラムを書いてみました。
ネットにはプログラムが山ほどあるのに、コピペだけで完結できる資料って意外と少ないですよね。私のようなめんどくさがり屋にとっては、もう少し標準ライブラリだけで構成されたサンプルコードが増えて欲しいな、とか、もっと直感的で分かりやすいライブラリを作ってほしいなとか思っています（他力本願）。
最後まで読んでいただきありがとうございました。
