40円マイコン+ArduinoでADCのアナログ値取得（analogRead）を使おうとしてハマった話

久しぶりにハマりました

この記事は？

秋月電子で40円で販売されているRISC-Vマイコン CH32V003で、Arduinoの開発環境を利用してADCのアナログ測定値を読みだす方法を説明します。
公式から用意されたArduinoだし簡単にできるかと思ったら、意外とハマりどころが多く時間がかかってしまいました。

環境・動かすコード

• CH32V003J4M6 （40円 RISC-V 8ピンマイコン）
• Arduino IDE 2
• openwch/arduino_core_ch32
• 周辺光ライトセンサ GA1A2S

Arduinoのライブラリとして、WCHが評価ボード用に出しているarduino_core_ch32を使用します。
一通りのライブラリ実装や書き込みプログラムなどが準備されていて、サクッと開発がコードを組んで動かすことができます。

開発環境は、下記サイトを参考にライタ（WCH LinkE）の設定変更とArduinoボードパッケージの用意をすればOKです。お手軽です。
40円RISC-Vマイコン(CH32V003)をArduino IDEでLチカをしてみました - きょうのかんぱぱ

マイコンはSOP-8パッケージの表面実装用なので、SOP-8用の変換基板を使ったり無理やり線をはんだ付けしたりして、入出力ができるようにします。
僕は以下のような簡単な基板を作りました。（汚いですが・・・）

Arduinoでアナログ値を読みだす、以下のシンプルなコードでAD変換値を正しく取得できるようにします。

※値の出力にプログラム書き込み（SDIO）と同じ8ピンのUART出力を使用するので、Serial.beginしてしまうとプログラムが書き込めなくなります。なので、下記コードでは起動時にプログラムを書き込む時間用のdelayを設けています。

#define ADC_PIN A2

void setup() {
// put your setup code here, to run once:
  delay(5000); // 注：UART初期化前に5秒待機（プログラム書き込みのため）
  Serial.begin(115200);
  pinMode(ADC_PIN,INPUT_ANALOG);
  Serial.println("Ready");
}

void loop() {
// put your main code here, to run repeatedly:
  uint16_t adc;
  adc = analogRead(ADC_PIN);
  Serial.println(adc);
  delay(100);
}

CH32V003J4M6は、6チャンネル 4ピンからAD値の取得が可能です。（下図：CH32V003 データシートより）

今回はアナログ入力のチャンネル0（A0 = 3pin）を使用します。

ADCに入力するアナログ信号は、周辺光センサGA1A2Sの出力を使用します。
アンプが内蔵されたフォトセンサで、3.3V電源を入力するとセンサ周辺の明るさに対応した電流を出力します。
抵抗（数kΩ）の一端を周辺稿センサの出力に、もう一端をGNDに接続しで電流が流れるようにしたうえで、センサ出力側をマイコンの3ピンに接続します。

結論（正しく動かす方法）

以下のようにすると、妥当なAD変換値が読めるようになります。

• variants\CH32V00x\CH32V003F4\variant_CH32V003F4.hのコメントアウトされているADC_MODULE_ENABLEDの定義をアンコメントする
• 以下のいずれかをする
  • system\CH32V00x\USER\system_ch32v00x.cのSYSCLK_FREQ_48MHz_HSEをコメントアウトし、代わりにSYSCLK_FREQ_xxMHZ_HSIのいずれかをアンコメントする
  • アナログ入力チャネルとしてA0（3ピン）、A1（1ピン）ではなくA2（7ピン）を使用する

ここより以下では、なににハマったのか？なぜそうなったのか？を説明します。

ハマり①：analogReadの戻り値が0固定になる

まず上記のコードを書き込んで実行すると、以下のようにanalogReadの戻り値が0だけになります。

原因と対策

これは、下記Issueで議論されている通り、ADCのモジュールを利用しない設定になっていることが原因です。

analogReadの実装を確認すると、ADC_MODULE_ENABLEDが定義されていない場合、何もせず0を返すようになっています。

このため、issueの回答にもあるとおり、ボードパッケージ内のvariants\CH32V00x\CH32V003F4\variant_CH32V003F4.h内でADC_MODULE_ENABLEが定義されるよう、コメントアウトを外します。

なお、arduino IDEのボードパッケージは、Windowsの場合デフォルトではC:\Users\{ユーザ名}\AppData\Local\Arduino15\packagesにあります。

コメントアウトを外して再度ビルドすると、0以外の値を返すようになります。

ハマり②：analogReadの戻り値が不安定な値になる。

ADC_MODULE_ENABLEDを定義したうえでビルドして実行すると、出力は以下のようになります。

一見正しく動いてそうですが、だいぶデタラメな出力になっています。
試しに、周辺稿センサにスマホのライトを近づけて出力を変化させ、それを測定して確認します。
真値として、ラズピコを使った簡易オシロ（PicoProbe）でアナログ値を40円マイコンと同時に測定し、比較してみます。

↓40円マイコンの出力（シリアル出力をExcleでグラフ化しています）

↓PicoProbeの出力

このとおり、精度とか言うまでもなく、全くデタラメな値を吐いています。
3.3Vを上限とする10bitのADCなので、測定波形（<1V）から考えると大体300前後の値が出るはずなのに、倍以上の値が出ています。また、ライトの移動に伴う入力値の変化に全く追従できていません。

原因と対策

関係ありそうなレジスタの設定値を出力して確認しました。
（確認用のコードは本記事の末尾に掲載します。）

出力結果は以下の通りでした。

RCC_CTLR: 0x13783
RCC_CFGR0: 0x0
RCC_APB2PCENR: 0x4025
GPIOA_CFGLR: 0x40
ADC_CTLR1: 0x0
ADC_CTLR2: 0x0
ADC_RSQR3: 0x0
RCC_CTLR: 0x13783
RCC_CFGR0: 0x0

ADC_CTLR2（下図：CH32V003マニュアルより）の最下位ビット ADONが0なのが気になりましたが、ライブラリの実装を確認するとanalogRead読み出し時に1にセットしていて、ここは問題ありませんでした。

気になったのはクロック設定であるRCC_CTLR（下図：CH32V003マニュアルより）の設定値です。

設定値は0x13783なので、16bitのHSEONが1、17bitのHSERDYが0になっています。
マニュアル（下図：CH32V003マニュアルより）によると、HSEONは外部入力クロック用のオシレータの設定ビット、HSERDYはそのオシレータの安定ビットです。

OSC_OUT（OSCO）はアナログ入力のチャンネル0（A0）と共通の3ピンを使っているので、関係がありそうです。
HSEONのreset valueは0なので、ライブラリ側で設定しているはずだと考えて調べたところ、system\CH32V00x\USER\system_ch32v00x.cで以下のように設定を行っていました。

同ファイル上部には、システムのクロックを設定できるマクロ定義があります。

システムクロックデフォルト設定が、外部クロックを使用する48MHzになっています。
おそらく、このArduinoライブラリがCH32V003の評価ボード向けに開発されているため、このようになっているのでしょう。
もちろん、外部クロックは搭載しないので、適切なクロック設定がなされるようにSYSCLK_FREQ_48MHz_HSEをコメントアウトし、代わりにSYSCLK_FREQ_xxMHZ_HSIのいずれかのコメントアウトを外します。これで、ADCを正しく使えるようになります。

ADCの動作を確認するため、この状態で再度ビルドし、先ほどと同様にスマホのライトを当てて出力をみてみます。

↓40円マイコンの出力

↓PicoProbeの出力

ラズピコオシロで取得した波形と、非常に近い形ので読めていることがわかります。
また、ラズピコオシロの測定上のVmaxが1.08Vなのに対し、40円マイコンではピークで300前後の値となっており、割と妥当な値になっているといえます。
アナログ値の読み出しくらい、サクッとできるかなと思っていたのですが、あまり思っていなかったところにはまりポイントがありました

補足1：ほかのチャンネルを使用する場合

アナログ入力のチャンネル0（A0）はHSE_Outと、チャンネル1（A1）はHSE_Inと機能がかぶっています。このため、A1（1ピン）をアナログ入力として使用しても、同じ現象が発生します。
一方、チャンネル2（A2）は7ピンを使用しており、HSEの機能とはかぶっていません。このため、ハマりポイント②の変更を加えなくても、正しくAD変換した値を取得できます。

補足2：クロック設定について

システムクロックを48MHz HSEに設定するSetSysClockTo_48MHz_HSEをよく見ると、HSEON設定後にHSEの安定を待っており、HSERDYが経つまでループを回ります。
ただし、このループにはタイムアウトが設定されており、一定時間経過してもフラグが経たない場合は次の処理に映るようになっています。

続く処理は以下のようになっています。

タイムアウト時はL404の分岐がFalseになり、L406以降の処理が実施されません。
L406以降ではクロックの設定（PLL onなど）を行っているのですが、すべてすっとばされてしまいます。つまり、想定された正しいクロック設定が一切なされていないままにsetup()関数までたどり着くことになります。

他ペリフェラル等の振舞は見ていないのですが、ADC同様正しく動かない可能性が高いと思われます。
ですので、補足1に書いたようにA2を使用する場合でも、このクロック設定は正しいものに変更しておいた方がいいでしょう。

補足3：レジスタ設定値出力用コード

#define ADC_PIN A0

// クロック関係
#define ADDR_RCC_CTLR ((volatile uint32_t *)(0x40021000))
#define ADDR_RCC_CFGR0 ((volatile uint32_t *)(0x40021004))
#define ADDR_RCC_APB2PCENR ((volatile uint32_t *)(0x40021018))

// GPIO関係
#define ADDR_GPIOA_CFGLR ((volatile uint32_t *)(0x40010800))

#define ADDR_ADC_CTLR1 ((volatile uint32_t *)(0x40012404))
#define ADDR_ADC_CTLR2 ((volatile uint32_t *)(0x40012408))
#define ADDR_ADC_RSQR3 ((volatile uint32_t *)(0x40012434))

void setup() {
// put your setup code here, to run once:
  delay(5000);
  Serial.begin(115200);
  pinMode(ADC_PIN,INPUT_ANALOG);
  Serial.println("Ready");
}

void loop() {
// put your main code here, to run repeatedly:
  uint32_t hoge;
  char fuga[50];

  hoge = *ADDR_RCC_CTLR;
  sprintf(fuga, "RCC_CTLR: 0x%lx", hoge);
  Serial.println(fuga);          // debug value
  hoge = *ADDR_RCC_CFGR0;
  sprintf(fuga, "RCC_CFGR0: 0x%lx", hoge);
  Serial.println(fuga);          // debug value
  hoge = *ADDR_RCC_APB2PCENR;
  sprintf(fuga, "RCC_APB2PCENR: 0x%lx", hoge);
  Serial.println(fuga);          // debug value
  hoge = *ADDR_GPIOA_CFGLR;
  sprintf(fuga, "GPIOA_CFGLR: 0x%lx", hoge);
  Serial.println(fuga);          // debug value
  hoge = *ADDR_ADC_CTLR1;
  sprintf(fuga, "ADC_CTLR1: 0x%lx", hoge);
  Serial.println(fuga);          // debug value
  hoge = *ADDR_ADC_CTLR2;
  sprintf(fuga, "ADC_CTLR2: 0x%lx", hoge);
  Serial.println(fuga);          // debug value
  hoge = *ADDR_ADC_RSQR3;
  sprintf(fuga, "ADC_RSQR3: 0x%lx", hoge);
  Serial.println(fuga);          // debug value

  delay(1000);
}