はじめに

この記事は、3DCG業界で働くArtist向けのMEL入門記事です。
普段の業務を効率化したいけど、MELの書き方が分からない、調べたけどイマイチ分からなかった、そんな方向けに書きました。
本記事は「if文を使う」をゴールとします。

環境

Autodesk Maya 2022.2

前回のあらすじと今回へのつなぎ

前回はfor文を学びました。繰り返し処理を扱えるようになったおかげで、一括系の処理が行いやすくなりましたね。
さて今回は前回作った「シーン内のすべてのジョイントの名前を、prefixが"jnt_"の名前にリネームするMEL」を少し改良していきます。
もう改良するところは無いよ、と思うかもしれませんが、実は結構大事なところが抜けていたりします。

大事なところって？

ずばり複数回の使用を想定していないところです。
具体的に見ていきましょう。
まずは前回のスクリプトの確認からです。

string $allJoints[] = `ls -type "joint"`;
string $jnt = "jnt_";
for ($joint in $allJoints) {
    rename $joint ($jnt + $joint);
}

試しに動作確認をしましょう。

実行すると、

正常に動きましたね。

さて、ここで一つ実際の仕事を想像してみましょう。

骨を設定し終わって上長に提出したあなたは、翌日にフィードバックを受けます。
「ここに骨を追加してほしい」

想像に難くないのではないでしょうか？

この際、どういう修正を行うかは重要ではありません。
重要なのは、骨に変更が入るため再度MELを実行する必要があるということです。

このような修正例のパターンを想定してみます。

新しく追加した骨にも「"jnt_"」を追加したいので再度スクリプトを実行します。

新しく追加した骨は正常にリネームされているようですが、
...あれ？今までの骨にも「jnt_」が追加されています。
「jnt_jnt_joint1」等の名前になっていますね。

...少々困ってしまいました。
現状のMELはすべての骨に「jnt_」を付ける処理になっているので、すでに「jnt_」が付いている骨もリネームしてしまうんですね。
どうも今知っている文法やコマンドだけでは修正が難しそうです。

実はこのような場合に対応するために、MELにはif文というものが存在します。

if文とは

簡単に言うと条件で処理を分岐することができる文です。

文法は下記です。

if (真偽値) {
    処理;
    ...(つづく)
}

for文と比べるとシンプルですね。
{}内はインデントを付けてください。

さて、まずは真偽値とはなにかを見ていきます。

真偽値とは

真偽値とは、「真」か「偽」かを表現する値です。
MEL上では真をtrue、偽をfalseで表現します。

スクリプトエディタでもハイライトが効くことからMELに内蔵されていることがわかります。
ちなみに英語ではbooleanと呼びます。もしかしたらMELコマンドリファレンス内で見たことがある人もいるかも知れません。あれはtrueもしくはfalseという意味です。
(ちなみに内部的には、trueは1、falseは0として扱われます。printすると1と0がそれぞれ出力されます)

真偽値とif文を使ってみる

早速使ってみましょう。

if (true) {
    print("Hello!!");
}

上記を実行すると、

「Hello!!」が出力されました。

真偽値の部分をfalseにするとどうなるでしょうか？

if (false) {
    print("Hello!!");
}

「Hello!!」は出力されませんでしたね。

つまりif文は真偽値がtrueなら{}内の処理を実行し、falseなら実行しないということになります。

真偽値を実践的に

突然ですが第7回で式というものを学んだことを覚えていますか？
簡単に振り返ると

それ自体が値を返すもの

です。
例としては「`getAttr "CubeA.translateX"`」「1 + 2」「10」なんかが挙げられていましたね。

さて、実はif文は真偽値部分に「真偽値を返す式」を書いても正常に動作します。
「true」はtrueを返す式なので、当然と言えば当然ですね。

ここで一つ真偽値を返す式を紹介します。

値 == 値
値 != 値

実際のMELだと、

if (3 == 3) {
    print("3は3です");
}
if (3 != 4) {
    print("3は4ではありありません");
}

上記のようなかたちになります。
==は等しければtrueを返します。数学と違って=が2つ必要な点に注意してください。
!=は等しくなければtrueを返します。ちょっと分かりづらいですが単純に条件を変転していると考えてください。

ちなみに文字列でも使用する事ができます。

if ("hum" == "hum") {
    print("humとhumは同じ文字列です");
}

少し実践的に書いてみましょう。
試しに、選択したものの名前が「"jnt_head"」かどうかを確認してみます。
「"jnt_head"」ならprintを行い、そうでないならなにもしません。

string $sels[] = `ls -sl`;
if ($sels[0] == "jnt_head") {
    print("jnt_headを選択しています");
}

jnt_headを選択した場合は正常にprintされます。

jnt_neckを選択した場合はどうでしょうか？

なにもprintされませんね。if文が正常に機能しているようです。

本題に戻り

さて、if文の使い方がわかったところで、本題の解決法を探っていきましょう。

問題点としては、すでにリネームされている骨も再度リネームしてしまうことにあります。
ということはすでにリネームされているかどうかを真偽値として取得し、if文と組み合わせればうまく行きそうです。
骨の名前に「"jnt_"」が含まれているかどうかで判断できそうな気がしますが一体どう行えばよいでしょうか？

文字列操作

MELには文字列を操作するコマンドがたくさん存在します。
今回はtokenizeコマンドが有効そうなので使い方を見ていきましょう。
使用例は下記です。

string $longWords = "apple_banana_orange";
string $fruits[];
tokenize $longWords "_" $fruits;
print($fruits);

実行している内容としては、「"apple_banana_orange"」という文字列を「"_"」で区切り、
バラバラになった「apple」「banana」「orange」を$fruitsに入れているという感じになります。
コマンドが変数に値を代入してくれるのは初ですね。

文法は下記です。

tokenize "分割したい文字列" "区切り文字列" 分割結果を入れる変数;

3つ目の「分割結果を入れる変数」というのが少し特殊で、事前に変数の宣言をしておく必要があります。
コマンドが実行されたら変数の中に結果を入れてくれます。
(ちなみにtokenizeコマンドは値を返すこともできます。返す値は分割できた文字列の数です(今回であれば3))

リネーム処理のリベンジ

さて、文字列の操作を学んだので、骨の名前に「"jnt_"」が含まれているかどうかを真偽値で取得することができそうです。
本命のMELに取り掛かる前に、肩慣らしとして選択した骨の名前のprefixが「jnt_」かどうかを判別する処理を書いてみます。

string $sels[] = `ls -sl`;
string $splitNames[];
tokenize $sels[0] "_" $splitNames;
string $prefix = $splitNames[0];

if ($prefix == "jnt") {
    print("選択したオブジェクトのprefixはjntです");
}

実行してみます。

問題なさそうですね。

さて次は本題です。前回のMELにこのリネーム処理を組み込んでみましょう。
for文とif文を組み合わせることになるので少し複雑ですが、頑張ってついてきてください。

string $allJoints[] = `ls -type "joint"`;
string $jnt = "jnt_";

for ($joint in $allJoints) {
    string $splitNames[];
    tokenize $joint "_" $splitNames;
    string $prefix = $splitNames[0];
    
    if ($prefix != "jnt") {
        rename $joint ($jnt + $joint);
    }
}

合体するとこんな感じになります。
結構複雑になってきましたね。

まずは動作を見ていきましょう。

うまくいきましたね！

処理が複雑なので、コメントで挙動の補足を行いたいと思います。

// シーン内の全てのjointを取得する
string $allJoints[] = `ls -type "joint"`;

// リネームする際の文字列を用意
string $jnt = "jnt_";

// $allJointsでforループを回す
for ($joint in $allJoints) {
    // tokenize結果の受け取り用変数を定義
    string $splitNames[];
    // $jointを「_」で分割する
    tokenize $joint "_" $splitNames;
    
    // $splitNamesの1つ目の要素はprefix
    string $prefix = $splitNames[0];
    
    // prefixが「jnt」ではないなら
    if ($prefix != "jnt") {
        // リネームする
        rename $joint ($jnt + $joint);
    }
}

一つずつ処理を読み、理解を深めていきましょう。
処理の途中で変数の中身をprintしてみるとわかりやすいかもしれません。

おわりに

いかがでしたか？
今回はfor文とif文、さらに文字列操作までを一度に行いました。
もしかしたら、今までの記事と比べるとちょっと難しかったかもしれません。ですがこれ以上難しいものはもうほとんど出てきません。
あるにはあるのですが、正直MELはfor文、if文、コマンドだけで大体の処理を書くことができます。言わば三種の神器です。

私はMELを書き始めのころはイマイチ理解しておらず、ただ文法に当てはめてを書いているだけでした。
しかし、書き続けていると不思議なもので、手になじむ瞬間があります。
みなさんもぜびMELを書き続けてもらえたらうれしいです。

次回→準備中