ネタの為に爆速と書きましたが実際は微増です。
ＯＳ本体のアニメーション効果を切る事で
負担軽減による高速化は定番でありますが
Ｏｆｆｉｃｅにもアニメーション効果があり
これらを纏めて切るバッチを作成しました。
これ以外にもチューニングポイントはありますので
興味のある方は下記のサイトを参考にして下さい。
Office 2016 (KB3114383) は 2015 年 12 月 8 日更新
https://support.microsoft.com/ja-jp/topic/office-2016-kb3114383-%E3%81%AF-2015-%E5%B9%B4-12-%E6%9C%88-8-%E6%97%A5%E6%9B%B4%E6%96%B0-57c61379-0001-af9f-fb93-565233b59d53
★ 2016 の Word で、ドキュメントにカスタム作業ウィンドウを表示するのに長い時間がかかる場合は、
カスタム作業ウィンドウの切り替え時のアニメーションを無効にする手順に従います。
Office のパフォーマンス トラブルシュート (その 3 : はじめに試す設定 - 描画編 -)
https://social.msdn.microsoft.com/Forums/ja-JP/12af26b8-6855-41af-a76c-e2da7c74ad0f/office-1239812497125011245712540125101253112473?forum=officesupportteamja%20rem%20/;
0. Office の設定変更手法
★ 1. アニメーションの無効化
2. リアルタイム プレビューの無効化
3. ハードウェア グラフィック アクセラレータの設定変更
4. シートの表示倍率
5. 図のリンク (カメラ)
6. 数式バー表示
7. ステータスバー表示
8. (プログラム向け) 描画処理全般の停止
9. (プログラム向け) Excel の非表示化
10. (OS) アニメーションの無効化
11. (OS) 視覚効果
★ 12. (OS) 省電力設定 ※ これは描画以外も含め、すべての動作に関わります
Office のパフォーマンス トラブルシュート (その 4 : はじめに試す設定 - 起動・オープン①、印刷編 -)
https://social.msdn.microsoft.com/Forums/ja-JP/ea9f89b7-a809-45ec-a8b5-6651e915f6bd/office-1239812497125011245712540125101253112473?forum=officesupportteamja
1. アドインの無効化
2. 既定のプリンターの変更
2-1. OS の[Windows で通常使うプリンターを管理する] をオフにする
2-2. 通常使うプリンターをローカルプリンターに変更する
3. ユーザー設定のビュー削除 (Excel 共有ブック)
4. 改ページ情報の非表示 (Excel)
5. ファイル・フォルダ履歴削除
6. ファイル検証の無効化
Office のパフォーマンス トラブルシュート (その 5 : はじめに試す設定 - 起動・オープン② -)
https://social.msdn.microsoft.com/Forums/ja-JP/6feb3f3f-93a2-4217-a723-4918a7229f69/office-1239812497125011245712540125101253112473?forum=officesupportteamja
1. SMB 通信設定 (ファイル サーバー上の共有フォルダのファイルを開く場合)
2. SharePoint からファイルを開くときのキャッシュ設定
3. インターネット サービスに接続する機能
4. 証明書有効性確認処理
Office のパフォーマンス トラブルシュート (その 6 : はじめに試す設定 - ファイル内容編 -)
https://social.msdn.microsoft.com/Forums/ja-JP/c537577f-1029-455f-9491-8bc56c013176/office-6-?forum=officesupportteamja
★ 1. Office クリップボードの無効化
※ こちらに加えてＯＳのクリップボード履歴のオフも効く事があります
★ 2. IME 予測入力の無効化
3. (Excel) 自動計算の無効化
※ メモリ不足やリソース不足に効く事があります
不足が解消したら、無効化解除をした方が安全です
4. (Excel) マルチスレッド処理の設定変更
5. (Excel) 書式設定範囲の最小化
6. 各種不要な書式設定の削除
@echo off
SetLocal EnableDelayedExpansion
rem /;
rem /; ★ Windowsトランジションの無効化
rem /;
rem /; Office 2016 (KB3114383) は 2015 年 12 月 8 日更新
rem /; https://support.microsoft.com/ja-jp/topic/office-2016-kb3114383-%E3%81%AF-2015-%E5%B9%B4-12-%E6%9C%88-8-%E6%97%A5%E6%9B%B4%E6%96%B0-57c61379-0001-af9f-fb93-565233b59d53
rem /;
rem /; 2016 の Word で、ドキュメントにカスタム作業ウィンドウを表示するのに長い時間がかかる場合は、
rem /; カスタム作業ウィンドウの切り替え時のアニメーションを無効にする手順に従います。
rem /;
rem /; Office のパフォーマンス トラブルシュート (その 3 : はじめに試す設定 - 描画編 -)
rem /; https://social.msdn.microsoft.com/Forums/ja-JP/12af26b8-6855-41af-a76c-e2da7c74ad0f/office-1239812497125011245712540125101253112473?forum=officesupportteamja
rem /;
rem /; 本記事では、Office 2016 / Office 2019 / Office 365 の Excel / Word / PowerPoint を対象に、
rem /; これらの設定項目を記載します。
rem /;
rem /; ★ アニメーションの無効化 (Excel / Word / PowerPoint)
rem /;
for /f "tokens=1-5 delims=\" %%1 in ('reg query "HKCU\Software\Microsoft\Office" /s ^| find /i "Common\Toolbars\"') do (
reg add "HKCU\Software\Microsoft\Office\%%5\Common\Toolbars" /f /v "DisableWindowTransitionsOnAddinTaskPanes" /t REG_DWORD /d "1" > nul 2> nul
reg add "HKCU\Software\Microsoft\Office\%%5\Common\Graphics" /f /v "DisableAnimations" /t REG_DWORD /d "1" > nul 2> nul
reg add "HKCU\Software\Microsoft\Office\%%5\Excel\Options" /f /v "EnableAnimations" /t REG_DWORD /d "0" > nul 2> nul
reg add "HKCU\Software\Microsoft\Office\%%5\Word\Options" /f /v "AnimateScreenMove" /t REG_DWORD /d "0" > nul 2> nul
)
@echo off
SetLocal EnableDelayedExpansion
rem /;
rem /; Office のパフォーマンス トラブルシュート (その 6 : はじめに試す設定 - ファイル内容編 -)
rem /; https://social.msdn.microsoft.com/Forums/ja-JP/c537577f-1029-455f-9491-8bc56c013176/office-6-?forum=officesupportteamja
rem /; 2. IME 予測入力の無効化
rem /;
rem /; 予測入力の無効化
rem /;
rem /; 文字コメントの無効化
rem /;
rem /; [Microsoft IME の設定] ダイアログの [詳細設定]
rem /;
rem /; ※ Office ではなく IME の設定のため、Office のバージョンに関わらず 15.0 の配下に設定します。
rem /;
rem /; [予測入力]タブ
rem /;
rem /; 設定 ---------------
rem /;
rem /; □ 予測入力を使用する ※ 下の２つが無効になると←も無効になる
rem /; ⇒ ⇒ ⇒ □ 入力履歴のデータを使用する "PredictionUseInputHistory"
rem /; ⇒ ⇒ ⇒ □ システム辞書のデータを使用する "PredictionUseSystemDictionary"
rem /;
rem /; [変換]タブ
rem /;
rem /; コメントの表示 ---------------
rem /;
rem /; ⇒ ⇒ ⇒ □ 文字コメントを表示する "ShowCharComment"
rem /; ⇒ ⇒ ⇒ □ "環境依存文字"のコメントを表示する "DisableCodeAreaForCodeComment"
rem /; ⇒ ⇒ ⇒ □ 単語コメントを表示する "ShowWordComment"
rem /;
reg add "HKCU\Software\Microsoft\IME\15.0\IMEJP\MSIME" /f /v "PredictionUseInputHistory" /t REG_DWORD /d "0" > nul 2> nul
reg add "HKCU\Software\Microsoft\IME\15.0\IMEJP\MSIME" /f /v "PredictionUseSystemDictionary" /t REG_DWORD /d "0" > nul 2> nul
reg add "HKCU\Software\Microsoft\IME\15.0\IMEJP\MSIME" /f /v "ShowCharComment" /t REG_DWORD /d "0" > nul 2> nul
reg add "HKCU\Software\Microsoft\IME\15.0\IMEJP\MSIME" /f /v "DisableCodeAreaForCodeComment" /t REG_DWORD /d "0x0000ffff" > nul 2> nul
reg add "HKCU\Software\Microsoft\IME\15.0\IMEJP\MSIME" /f /v "ShowWordComment" /t REG_DWORD /d "0" > nul 2> nul
@echo off
SetLocal EnableDelayedExpansion
rem /;
rem /; Office のパフォーマンス トラブルシュート (その 6 : はじめに試す設定 - ファイル内容編 -)
rem /; https://social.msdn.microsoft.com/Forums/ja-JP/c537577f-1029-455f-9491-8bc56c013176/office-6-?forum=officesupportteamja
rem /; 1. Office クリップボードの無効化
rem /;
for /f "tokens=1-5 delims=\" %%1 in ('reg query "HKCU\Software\Microsoft\Office" /s ^| find /i "Common\Toolbars\"') do (
reg add "HKCU\Software\Microsoft\Office\%%5\Common\General" /f /v "AcbControl" /t REG_DWORD /d "0x80000000" > nul 2> nul
)
@echo off
rem /;
rem /; ★ 電源設定を「究極のパフォーマンス」に設定後、電源オプションを表示
rem /;
rem /; 電源設定は、下記の４種類ありますが
rem /; 初期表示状態で、省電力 と バランス だけの物があります
rem /;
rem /; 省電力 ＜ バランス ＜ 高パフォーマンス ＜ 究極のパフォーマンス
rem /;
rem /; このバッチは、一旦、「高パフォーマンス」を設定し
rem /; 設定可能な場合は「究極のパフォーマンス」を設定します
rem /; 機種によって「究極」設定が存在しない場合がありますので
rem /; 高パフォーマンスを選択する事になります
rem /;
rem /; デスクトップ機は、「究極のパフォーマンス」設定でいいかと思いますが
rem /; ノート・タブレットの場合、ＡＣ駆動・バッテリ駆動で運用が分かれますので
rem /; バランスを選んで、ＡＣ駆動はフルパワー・バッテリ駆動は節電モードで
rem /; 運用する事が無難です
rem /;
:高パフォーマンスに設定
PowerCfg /S 8c5e7fda-e8bf-4a96-9a85-a6e23a8c635c
PowerCfg /L | find "究極のパフォーマンス" > nul && goto :★究極のパフォーマンスに設定
:究極のパフォーマンス設定を追加
PowerCfg -DuplicateScheme e9a42b02-d5df-448d-aa00-03f14749eb61 > nul 2> nul || goto :◆電源オプションを表示
:★究極のパフォーマンスに設定
For /f "tokens=3 delims= " %%3 in ('PowerCfg /L ^| find "究極のパフォーマンス"') do PowerCfg /S %%3
:◆電源オプションを表示
Powercfg.cpl
rem /;
rem /; 究極のパフォーマンスを選択すると高パフォーマンス設定が消える場合があります
rem /;