More than 5 years have passed since last update.

日本一マクドナルドから遠い場所　をより精確に求めてみた

Last updated at 2018-05-02Posted at 2018-05-02

経緯と目的

j_catfish氏の日本一マクドナルドから遠い場所の面白い着想に触発され、地図大好き人間として自分も書きたくなった。

目的としては以下の通り。

Google Maps APIは地球を回転楕円体ではなく球として距離の計算をするので、最大0.3%程度の誤差が出る
この誤差がもしかしたら結果に影響を与えるかもしれない、せたな町と知床の距離の検証を行う

データの用意

今回用意したデータは以下の2つ。

基盤地樹情報ダウンロードサービスから海岸線データ
- せたな町の一部(2次メッシュ番号で633926、633936、633946の3箇所)
- 知床半島の先端部(2次メッシュ番号で664532, 664542の2箇所)
日本マクドナルドの店舗検索ページから、店舗の位置情報JSONを開発者ツールを使って保存
- せたな町近辺のマクドナルド店舗のJSON(店舗数68)
- 知床半島近辺のマクドナルド店舗のJSON(店舗数26)

計算を高速化するため、範囲を絞った。

ちなみに、具体的にどの店舗なのか不明なのだが、元記事の時点ではマクドナルドの総店舗数が2887だったのが、2018年5月2日時点では1店舗減って2886になっていた。(追記: 2887店に戻ってました)

計算

測地線の距離計算には、誤差15nmと言われるGeographicLibをJ/Link経由でMathematicaから呼び出す、拙作のパッケージmathematica-geodesicを使用した。

せたな町

まずは海岸線データのXMLファイルを読み込み、posList要素に記述された緯度経度データを抜き出す。
海岸線データには岩礁なども含まれるため、始点と終点の座標が同じになっているものは除去した。

なお海岸線データのCurve要素は、海岸線の管理者(国か県か)といった行政の都合によってバラバラに分割されていて非常に使いにくい。
そのため完全には除去できていないのだが、今回は最遠点を求めるのに支障がなければよしとする。

xmlfiles1 = FileNames["data00/FG-GML-63*.xml"];
xmldata1 = Import /@ xmlfiles1;

curves1 = 
  Flatten[Cases[#, XMLElement[{_, "Curve"}, _, _], Infinity] & /@ 
    xmldata1, 1];

coastpoints1 = 
  Flatten[Select[
    Partition[
       Flatten[Cases[#, 
         XMLElement[{_, "posList"}, _, 
           a_] :> (ToExpression /@ StringSplit[a, Whitespace]), 
         Infinity]], 2] & /@ curves1, First@# != Last@# &], 1];

抜き出した緯度経度データの個数は5990。

In[5]:= Length[coastpoints1]
Out[5]= 5990

次にせたな町周辺のマクドナルド店舗のJSONから、緯度経度データを抜き出す。

mcdonalds1 = {"latitude", "longitude"} /. Import["mcdonalds_setana.json"];

こちらのデータの個数は68。

In[7]:= Length[mcdonalds1]

Out[7]= 68

海岸線の緯度経度データとマクドナルド店舗の緯度経度データのすべての組み合わせの距離を求める。
一般化した外積Outerを使うと一発で楽ちん。

<< Geodesic`
dists1 = Min /@ Outer[GeoDistanceGL, coastpoints1, mcdonalds1, 1];

さて・・・結果は？

In[17]:= Max[dists1]

Out[17]= 93357.2

In[24]:= coastpoints1[[Ordering[dists1, -1]]]

Out[24]= {{42.3029, 139.767}}

緯度経度はFullFormで精確な値を出して、せたな町のマクドナルド最遠点の位置は

緯度: 42.302894444°
経度: 139.766917778°
距離: 93.357 km

尾花岬の北にも2つほど突端部があるが、そこではなく尾花岬。

知床

知床半島突端のデータに対しても同様に計算。

In[10]:= xmlfiles2 = FileNames["data00/FG-GML-66*.xml"];

In[11]:= xmldata2 = Import /@ xmlfiles2;

In[12]:= coastpoints2 = 
 Flatten[Select[
   Partition[
      Flatten[Cases[#, 
        XMLElement[{_, "posList"}, _, 
          a_] :> (ToExpression /@ StringSplit[a, Whitespace]), 
        Infinity]], 2] & /@ curves2, First@# != Last@# &], 1]

In[13]:= Length[coastpoints2]

Out[13]= 6375

In[14]:= mcdonalds2 = {"latitude", "longitude"} /. 
   Import["mcdonalds_shiretoko.json"];

In[15]:= Length[mcdonalds2]

Out[15]= 26

In[18]:= dists2 = 
  Min /@ Outer[GeoDistanceGL, coastpoints2, mcdonalds2, 1];

In[19]:= Max[dists2]

Out[19]= 92740.

In[25]:= coastpoints2[[Ordering[dists2, -1]]]

Out[25]= {{44.3389, 145.345}}