ERC20 Token Standard Interface の紹介
合同会社kumanoteのTanakaです。
趣味でEthereumのマイニングをやっています。
マイニング楽しいんですが、わりとプログラムから離れた領域で、
やっぱり自分で何か作ってみたいと思うようになり・・Smart ContractでTokenを作ることにしました。
できれば、作ったものを公開し、今後の事業につながるところまで発展できたらと考えています。
色々調べて、Smart ContractでTokenを作るには、ERC20 Token Standardを満たしている
Contractを作った方が良さそうだと感じたのでそのように実装するつもりです。
今回は、その ERC20 Token Standard Interface の実装方法を紹介します。
ERC20Interface.solファイルの作成
Layout of a Solidity Source File — Solidity 0.4.14 documentationが参考になりました。
Solidity supports import statements that are very similar to those available in JavaScript (from ES6 on), although Solidity does not know the concept of a “default export”.
solidityの開発時に規模がそこそこ大きくなる場合などのために
ファイルを分割して、他のファイルを参照することができます。
JavascriptのES6のimport
と同じような記法が使えるとのことです。
そこで、先ずは ERC20Interface
の定義だけを記載した sol
ファイルを作ってみます。
ERC20Interface.sol
pragma solidity ^0.4.11;
// ERC Token Standard #20 Interface
// https://github.com/ethereum/EIPs/issues/20
contract ERC20Interface {
// Get the total token supply
function totalSupply() constant returns (uint256 totalSupply);
// Get the account balance of another account with address _owner
function balanceOf(address _owner) constant returns (uint256 balance);
// Send _value amount of tokens to address _to
function transfer(address _to, uint256 _value) returns (bool success);
// Send _value amount of tokens from address _from to address _to
function transferFrom(address _from, address _to, uint256 _value) returns (bool success);
// Allow _spender to withdraw from your account, multiple times, up to the _value amount.
// If this function is called again it overwrites the current allowance with _value.
// this function is required for some DEX functionality
function approve(address _spender, uint256 _value) returns (bool success);
// Returns the amount which _spender is still allowed to withdraw from _owner
function allowance(address _owner, address _spender) constant returns (uint256 remaining);
// Triggered when tokens are transferred.
event Transfer(address indexed _from, address indexed _to, uint256 _value);
// Triggered whenever approve(address _spender, uint256 _value) is called.
event Approval(address indexed _owner, address indexed _spender, uint256 _value);
}
ERC20Interfaceの実装クラスを作成
ERC20Interface.sol と同一のディレクトリにファイルを作成します。
FixedSupplyToken.sol
ポイントとしては
-
import
文にて同一ディレクトリのERC20Interface.sol
ファイルを指定することで、ERC20Interface
を使用することができます。 -
FixedSupplyToken
はERC20Interface
で指定されている各種のメソッドを実装する必要があります。
pragma solidity ^0.4.8;
import "./ERC20Interface.sol";
contract FixedSupplyToken is ERC20Interface {
string public constant symbol = "FIXED";
string public constant name = "Example Fixed Supply Token";
uint8 public constant decimals = 18;
uint256 _totalSupply = 1000000;
// Owner of this contract
address public owner;
// Balances for each account
mapping(address => uint256) balances;
// Owner of account approves the transfer of an amount to another account
mapping(address => mapping (address => uint256)) allowed;
// Functions with this modifier can only be executed by the owner
modifier onlyOwner() {
require(msg.sender == owner);
_;
}
// Constructor
function FixedSupplyToken() {
owner = msg.sender;
balances[owner] = _totalSupply;
}
function totalSupply() constant returns (uint256 totalSupply) {
totalSupply = _totalSupply;
}
// What is the balance of a particular account?
function balanceOf(address _owner) constant returns (uint256 balance) {
return balances[_owner];
}
// Transfer the balance from owner's account to another account
function transfer(address _to, uint256 _amount) returns (bool success) {
if (balances[msg.sender] >= _amount
&& _amount > 0
&& balances[_to] + _amount > balances[_to]) {
balances[msg.sender] -= _amount;
balances[_to] += _amount;
Transfer(msg.sender, _to, _amount);
return true;
} else {
return false;
}
}
// Send _value amount of tokens from address _from to address _to
// The transferFrom method is used for a withdraw workflow, allowing contracts to send
// tokens on your behalf, for example to "deposit" to a contract address and/or to charge
// fees in sub-currencies; the command should fail unless the _from account has
// deliberately authorized the sender of the message via some mechanism; we propose
// these standardized APIs for approval:
function transferFrom(
address _from,
address _to,
uint256 _amount
) returns (bool success) {
if (balances[_from] >= _amount
&& allowed[_from][msg.sender] >= _amount
&& _amount > 0
&& balances[_to] + _amount > balances[_to]) {
balances[_from] -= _amount;
allowed[_from][msg.sender] -= _amount;
balances[_to] += _amount;
Transfer(_from, _to, _amount);
return true;
} else {
return false;
}
}
// Allow _spender to withdraw from your account, multiple times, up to the _value amount.
// If this function is called again it overwrites the current allowance with _value.
function approve(address _spender, uint256 _amount) returns (bool success) {
allowed[msg.sender][_spender] = _amount;
Approval(msg.sender, _spender, _amount);
return true;
}
function allowance(address _owner, address _spender) constant returns (uint256 remaining) {
return allowed[_owner][_spender];
}
}
throwについて
throw
をつかうと
Warning: "throw" is deprecated in favour of "revert()", "require()" and "assert()".
っていう警告でるので
throw
は使わずに、できる限り、revert
, require
, assert
を使うようにした方がよさそうです。
↑ の例でいえば、以下の箇所で throw
の使用をさけました。
modifier onlyOwner() {
if (msg.sender != owner) {
throw;
}
_;
}
を以下のように修正しました。
modifier onlyOwner() {
require(msg.sender == owner);
_;
}
以上になります。