複数のプロジェクトで使いまわしたいクラスは、アドインとして外部に置いておいて別のExcel VBAから参照できると便利です。（たぶん）

やり方

1. ふつうにクラスモジュールを作成する

ここではClassInXlamという名称にします。

ClassInXlam(クラスモジュール)

Option Explicit

Public str As String

' strの中身を表示する
Public Sub ShowStr()
    Debug.Print "str=" & str
End Sub

2. 外部からインスタンスを取得するための関数を追加する

外部からは直接Newできないため、標準モジュールを追加し、外部からインスタンスを取得するための関数を書きます。
ここではモジュールはRootという名称にしています。

Root(標準モジュール)

Option Explicit

Public Function CreateClassInXlam(str As String) As ClassInXlam
    Dim tmpClass As ClassInXlam

    Set tmpClass = New ClassInXlam
    tmpClass.str = str

    Set CreateClassInXlam = tmpClass
End Function

3. クラスのプロパティをPublicNotCreatableにする

プロパティウインドウから、クラスのInstancingプロパティを2 - PublicNotCreatableにします。
（完全なPublicには設定できません。）
これで外部からクラス名が使えるようになります。

4. プロジェクトの名称を変更する

デフォルトのVBAProjectのままでは、他ファイルから参照したときに名称が競合してエラーになります。
プロジェクトエクスプローラから対象のプロジェクトを右クリックして適当な名称に変更します。

5. Excelアドイン形式で保存する

名前を付けて保存で、「.xlam」形式を選択して保存します。
ここまででアドイン側の準備は終了です。

外から参照してみる

新しいブックを開いて、そこから参照してみます。

1. アドインへ参照設定をする

VBEの「ツール」>「参照設定」ダイアログの「参照」から、先ほど作成したxlamファイルを選択します。
「OK」を押すと、プロジェクトエクスプローラの「参照設定」のところに参照先として追加されています。

2. 使う

こんな感じで使えます。
Intellisenseも使えます。

標準モジュール

Option Explicit

Sub test()
    Dim instanceOfClass As ClassInXlam

    Set instanceOfClass = CreateClassInXlam("test")

    instanceOfClass.ShowStr ' => str=test
End Sub

外からインスタンス化するインターフェースについて

以下のようにすると、ClassInXlam.Create()と書けてStaticメソッドから作成できているように見えてかっこいいです。

1. クラスモジュールにCreateメソッドを作成する

Createメソッドは、外部ファイルからインスタンスを作れるようにするためです。

ClassInXlam(クラスモジュール)

Option Explicit

Public str As String

' strの中身を表示する
Public Sub ShowStr()
    Debug.Print "str=" & str
End Sub

' ちなみにCreateには引数も渡せる
Public Function Create(str As String) As ClassInXlam
    Dim tmpClass As ClassInXlam

    Set tmpClass = New ClassInXlam
    tmpClass.str = str

    Set Create = tmpClass
End Function

2. インスタンス生成用のパブリック変数をつくる

アドイン側のRootモジュールの内容を以下のようにします。